Haskell 弱头范式

Question

我被一些烦人的事情绊倒了。 我知道 haskell 与弱头部范式 (WHNF) 一起工作，我知道这是什么。 将以下代码输入 ghci（我正在使用命令 :sprint 将表达式简化为 WHNF，据我所知。）：

let intlist = [[1,2],[2,3]]
:sprint intlist

给出intlist = _这对我来说完全有意义。

let stringlist = ["hi","there"]
:sprint stringlist 

给出stringlist = [_,_]这已经让我感到困惑。 但是之后：

let charlist = [['h','i'], ['t','h','e','r','e']]
:sprint charlist

令人惊讶的是charlist = ["hi","there"]

据我了解 Haskell，字符串只不过是字符列表，这似乎可以通过检查类型"hi" :: [Char]和['h','i'] :: [Char] 。

我很困惑，因为根据我的理解，上面的所有三个示例或多或少都相同（列表列表），因此应该减少到相同的 WHNF，即 _。 我错过了什么？

谢谢

Answer 1

需要注意的是:sprint不会减少WHNF的表达式。 如果是这样，那么以下将给出4而不是_ ：

Prelude> let four = 2 + 2 :: Int
Prelude> :sprint four
four = _

相反， :sprint使用绑定的名称，遍历绑定值的内部表示，并显示已经“评估的部分”（即构造函数的部分），同时使用_作为未评估的 thunk 的占位符（即，暂停延迟函数调用）。 如果该值完全未评估，则不会进行评估，甚至不会对 WHNF 进行评估。 （如果该值被完全评估，你会得到它，而不仅仅是 WHNF。）

您在实验中观察到的是多态与单态数字类型的组合、字符串文字与显式字符列表的不同内部表示等。基本上，您正在观察不同文字表达式如何编译为字节码的技术差异。 因此，将这些实现细节解释为与 WHNF 有关系会让您感到非常困惑。 通常，您应该将:sprint仅用作调试工具，而不是了解 WHNF 和 Haskell 评估语义的一种方式。

如果你真的想了解:sprint正在做什么，你可以在 GHCi 中打开一些标志来查看表达式实际上是如何处理的，因此最终编译为字节码：

> :set -ddump-simpl -dsuppress-all -dsuppress-uniques

在此之后，我们可以看到您的intlist给出_的原因：

> let intlist = [[1,2],[2,3]]
==================== Simplified expression ====================
returnIO
  (: ((\ @ a $dNum ->
         : (: (fromInteger $dNum 1) (: (fromInteger $dNum 2) []))
           (: (: (fromInteger $dNum 2) (: (fromInteger $dNum 3) [])) []))
      `cast` <Co:10>)
     [])

您可以忽略returnIO和外部:调用，并专注于以((\\ @ a $dNum -> ...

这里$dNum是Num约束的字典。 这意味着生成的代码尚未解析类型Num a => [[a]]的实际类型a ，因此整个表达式仍表示为采用（字典）适当Num类型的函数调用。 换句话说，这是一个未经评估的 thunk，我们得到：

> :sprint intlist
_

另一方面，指定类型为Int ，代码完全不同：

> let intlist = [[1::Int,2],[2,3]]
==================== Simplified expression ====================
returnIO
  (: ((: (: (I# 1#) (: (I# 2#) []))
         (: (: (I# 2#) (: (I# 3#) [])) []))
      `cast` <Co:6>)
     [])

:sprint输出也是如此：

> :sprint intlist
intlist = [[1,2],[2,3]]

同样，文字字符串和显式字符列表具有完全不同的表示形式：

> let stringlist = ["hi", "there"]
==================== Simplified expression ====================
returnIO
  (: ((: (unpackCString# "hi"#) (: (unpackCString# "there"#) []))
      `cast` <Co:6>)
     [])

> let charlist = [['h','i'], ['t','h','e','r','e']]
==================== Simplified expression ====================
returnIO
  (: ((: (: (C# 'h'#) (: (C# 'i'#) []))
         (: (: (C# 't'#)
               (: (C# 'h'#) (: (C# 'e'#) (: (C# 'r'#) (: (C# 'e'#) [])))))
            []))
      `cast` <Co:6>)
     [])

并且:sprint输出中的差异代表了 GHCi 认为已评估（显式:构造函数）与未评估（ unpackCString# ）的表达式部分的工件。