将本地动态数组的长度设置为零会减少内存使用吗？

Question

将本地动态数组的长度设置为零（不再需要时）是否对内存使用有好处？

例如：

var
  MyArray : array of string;
begin
  <filling my array with a lot of items....>

  <doing some stuffs with MyArray>

  //from here on, MyArray is no more needed, should I set its length to zero?
  SetLength(MyArray, 0);

  <doing other stuffs which doesn't need MyArray...>
end;

Answer 1

在 Delphi 中， 动态数组是引用计数的。

因此，如果你这样做

MyArray := nil;

或者

Finalize(MyArray);

或者

SetLength(MyArray, 0);

变量MyArray将不再指向动态数组堆对象，因此它的引用计数将减少 1。如果这使引用计数降为零，意味着没有变量指向它，它将被释放。

示例 1

所以在

var
  a: array of Integer;
begin

  SetLength(a, 1024*1024);

  // ...

  SetLength(a, 0);

  // ...

end

您将释放SetLength(a, 0)上的内存，假设a是唯一指向此堆对象的变量。

示例 2

var
  b: TArray<Integer>;

procedure Test;
var
  a: TArray<Integer>;
begin

  SetLength(a, 1024*1024);

  b := a;

  SetLength(a, 0);

  // ...

end

SetLength(a, 0)不会释放任何内存，因为b仍然指的是原始数组。 不过，它会将引用计数从 2 减少到 1。

示例 3

而且，当然，在

var
  a: array of Integer;
begin

  SetLength(a, 1024*1024);

  // ...

  SetLength(a, 0);

end

最后一次调用SetLength是完全没有必要的，因为局部变量a无论如何都会在下一行代码中超出范围，这也减少了堆对象的引用计数。

Answer 2

是的，当您将动态数组的长度设置为零时，如果没有其他变量/对象正在引用内存（不一定返回到 Windows 内存，因此您可能看不到），它正在使用的内存将被释放回可用的堆内存任务管理器中的好处，但您的 Delphi 程序需要从 Windows 分配额外的内存需要更长的时间，因为它将首先使用可用的堆内存，您已向其中添加了“MyArray”的大小）。