如何从 .bat 文件运行多个服务

Question

我想从 bat 文件运行 selenium 服务器。 表示启动集线器和集线器下的两个节点。 在 Ubuntu 我有这个脚本来做到这一点：

  java -jar $jarFilePath -role hub & 
  java -jar $jarFilePath -role node -hub http://173.249.58.30:4444/grid/register/ & 
  java -jar $jarFilePath -role node -hub http://173.249.58.30:4444/grid/register/ & 
  exit 0

有必要用 & 链接它，因为第一个命令仍在运行并且不运行下一个命令。 但是在 Windows 上，由于某些原因，这不起作用。 我为 Win 找到了类似的东西，但仍然没有成功。 它打开三个终端，但节点无法注册到集线器：

start cmd.exe /k "cd c:\Program Files\Selenium\Server & java -jar selenium-server-standalone-3.141.59.jar -role hub"

start cmd.exe /k "cd c:\Program Files\Selenium\Server & java -jar selenium-server-standalone-3.141.59.jar -role node -hub http://192.168.137.1:4444/grid/register/" 
start cmd.exe /k "cd c:\Program Files\Selenium\Server & java -jar selenium-server-standalone-3.141.59.jar -role node -hub http://192.168.137.1:4444/grid/register/" 

谢谢你的帮助。

Answer 1

您的命令失败的原因是必须引用带有空格的路径（空格是标记分隔符）。

但是以下仍然会失败，因为引号不能嵌套，所以&没有被引用，并且初始批处理解析器将该行视为两个连接的命令而不是单个start命令。

例如，看第一行，这是行不通的

start cmd.exe /k "cd "c:\Program Files\Selenium\Server" & java -jar selenium-server-standalone-3.141.59.jar -role hub"

要解决上述问题，很多人会逃避&

start cmd.exe /k "cd "c:\Program Files\Selenium\Server" ^& java -jar selenium-server-standalone-3.141.59.jar -role hub"

但我更喜欢转义最外面的引号，这样我就可以编写命令，就像我自己在命令提示符中键入它们一样

start cmd.exe /k "cd ^"c:\Program Files\Selenium\Server" & java -jar selenium-server-standalone-3.141.59.jar -role hub^"

请注意，默认情况下cd不会更改您的活动驱动器。 所以说你的活动驱动器是D: ，那么上面的仍然行不通。 您必须使用cd /d "c:\Program Files\Selenium\Server"或pushd "c:\Program Files\Selenium\Server" 。

但是在您的start命令之前cd /d或pushd可能更简单，因此您只需执行一次。 START ed 进程继承父进程的环境。

服务终止后，子进程不需要保持打开状态，因此最好使用cmd /c而不是cmd /k 。

您的完整脚本可能是

@echo off
pushd "c:\Program Files\Selenium\Server"
start cmd.exe /c "java -jar selenium-server-standalone-3.141.59.jar -role hub"
start cmd.exe /c "java -jar selenium-server-standalone-3.141.59.jar -role node -hub http://192.168.137.1:4444/grid/register/" 
start cmd.exe /c "java -jar selenium-server-standalone-3.141.59.jar -role node -hub http://192.168.137.1:4444/grid/register/" 
popd

但我不确定您是否真的需要在java内显式运行cmd.exe 。 您也许可以简单地使用以下内容

@echo off
pushd "c:\Program Files\Selenium\Server"
start java -jar selenium-server-standalone-3.141.59.jar -role hub
start java -jar selenium-server-standalone-3.141.59.jar -role node -hub http://192.168.137.1:4444/grid/register/
start java -jar selenium-server-standalone-3.141.59.jar -role node -hub http://192.168.137.1:4444/grid/register/
popd

最后，您可能不需要为每个进程使用单独的 window，在这种情况下，您可以将/B选项添加到START命令。 start后立即放置。