在 Raku 中，如何編寫等效於 Haskell 的 span 函數？

Question

---

在 Raku 中，如何編寫等效於 Haskell 的span函數？

在 Haskell 中，給定一個謂詞和一個列表，可以將列表分成兩部分：

• 滿足謂詞的元素的最長前綴
• 列表的其余部分

例如，Haskell 表達式……

span (< 10) [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4]

……評估為……

([2,2,2,5,5,7],[13,9,6,2,20,4])

如何編寫與 Haskell 的span函數等效的 Raku？

---

更新 1

根據@chenyf 的回答，我開發了以下span子例程（稍后的附加更新反映了span內的否定謂詞需要保持忠實於Haskell 的span函數的正邏輯）......

sub span( &predicate, @numberList )
  {
  my &negatedPredicate = { ! &predicate($^x) } ;
  my $idx = @numberList.first(&negatedPredicate):k ;
  my @lst is Array[List] = @numberList[0..$idx-1], @numberList[$idx..*] ;
  @lst ;
  } # end sub span

sub MAIN()
  {
  my &myPredicate = { $_ <= 10 } ;
  my @myNumberList is Array[Int] = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4] ;
  my @result is Array[List] = span( &myPredicate, @myNumberList ) ;

  say '@result is ...' ;
  say @result ;
  say '@result[0] is ...' ;
  say @result[0] ;
  say @result[0].WHAT ;
  say '@result[1] is ...' ;
  say @result[1] ;
  say @result[1].WHAT ;
  } # end sub MAIN

程序輸出是……

@result is ...
[(2 2 2 5 5 7) (13 9 6 2 20 4)]
@result[0] is ...
(2 2 2 5 5 7)
(List)
@result[1] is ...
(13 9 6 2 20 4)
(List)

---

更新 2

利用發布到StackOverflow上的有關 Raku 的Nil的信息，以下子例程span的更新草案是……

sub span( &predicate, @numberList )
  {
  my &negatedPredicate = { ! &predicate($^x) } ;
  my $idx = @numberList.first( &negatedPredicate ):k ;
  if Nil ~~ any($idx) { $idx = @numberList.elems ; }
  my List $returnList = (@numberList[0..$idx-1], @numberList[$idx..*]) ;
  $returnList ;
  } # end sub span

sub MAIN()
  {
  say span( { $_ == 0 }, [2, 2, 5, 7, 4, 0] ) ;  #  (() (2 2 5 7 4 0))
  say span( { $_ <  6 }, (2, 2, 5, 7, 4, 0) ) ;  #  ((2 2 5) (7 4 0))
  say span( { $_ != 9 }, [2, 2, 5, 7, 4, 0] ) ;  #  ((2 2 5 7 4 0) ())
  } # end sub MAIN

---

Answer 1

我使用first一種方法和:k副詞，如下所示：

my @num  = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4];
my $idx = @num.first(* > 10):k;

@num[0..$idx-1], @num[$idx..*];

Answer 2

一個完全天真的看法：

sub split_on(@arr, &pred) {
  my @arr1;
  my @arr2 = @arr;

  loop {
    if not &pred(@arr2.first) {
      last;
    } 

    push @arr1: @arr2.shift
  }

  (@arr1, @arr2);
}

創建一個新的@arr1並將數組復制到@arr2中。 循環，如果數組中的第一個元素不滿足謂詞，則為最后一次。 否則，將第一個元素從@arr2移出並將其推送到@arr1上。

測試時：

my @a = [2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4];
my @b = split_on @a, -> $x { $x < 10 };

say @b;

輸出是：

[[2 2 2 5 5 7] [13 9 6 2 20 4]]

這里唯一的問題是......如果不滿足謂詞怎么辦？ 好吧，讓我們檢查列表是否為空或不滿足謂詞來終止循環。

sub split_on(@arr, &pred) {
  my @arr1;
  my @arr2 = @arr;

  loop {
    if !@arr2 || not &pred(@arr2.first) {
      last;
    } 

    push @arr1: @arr2.shift;
  }

  (@arr1, @arr2);
}

Answer 3

在Raku (*each) 的 1 行* 中的 105 個 C++ 算法的演講中，Daniel Sockwell 討論了一個幾乎可以回答您的問題的函數。 我已經對其進行了一些重構以適應您的問題，但變化很小。

#| Return the index at which the list splits given a predicate.
sub partition-point(&p, @xs) {
    my \zt = @xs.&{ $_ Z .skip };
    my \mm = zt.map({ &p(.[0]) and !&p(.[1]) });
    my \nn = mm <<&&>> @xs.keys;
    return nn.first(?*)
}

#| Given a predicate p and a list xs, returns a tuple where first element is
#| longest prefix (possibly empty) of xs of elements that satisfy p and second
#| element is the remainder of the list.
sub span(&p, @xs) {
    my \idx = partition-point &p, @xs;
    idx.defined ?? (@xs[0..idx], @xs[idx^..*]) !! ([], @xs)
}

my @a = 2, 2, 2, 5, 5, 7, 13, 9, 6, 2, 20, 4;
say span { $_ < 10 }, @a;                #=> ((2 2 2 5 5 7) (13 9 6 2 20 4))
say span { $_ < 5 }, [6, 7, 8, 1, 2, 3]; #=> ([] [6 7 8 1 2 3])

Answer 4

所以我想我會把我的版本扔進去，因為我認為classify可能會有所幫助：

sub span( &predicate, @list ) { 
    @list
    .classify({
        state $f = True; 
        $f &&= &predicate($_); 
        $f.Int; 
    }){1,0}
    .map( {$_ // []} )
}

最后的map用於處理謂詞永遠不為真或總是為真的情況。

Answer 5

版本 6.e 的 raku 將采用新的“snip”功能：

use v6.e; 
dd (^10).snip( < 5 );
#«((0, 1, 2, 3, 4), (5, 6, 7, 8, 9)).Seq␤»