是否可以通过包装或cython重新声明gsl_function将cython类方法分配给gsl_function结构？

Question

这个问题是基于这里的问题

我有以下cython代码，该代码导入一个文件（ cGslInteg.pxd ），其中包含gsl/gsl_integration.h和gsl/gsl_math.h头文件的相关部分的cython声明，然后定义一个用于计算积分的类：

from libc.math cimport log
from libc.math cimport sqrt
from cGslInteg cimport *

ctypedef double * double_ptr

cdef double integrand(double x, void * params):
    """integrand implemented outside class """

    cdef double alpha = (<double_ptr> params)[0]
    cdef double f = log(alpha*x) / sqrt(x)
    return f


cdef class CalcSomething(object):

    def integrate(self, double a, double b, double alpha):
        """This does the integral"""

        cdef double result, error

        cdef gsl_integration_workspace * W
        W = gsl_integration_workspace_alloc(1000)

        cdef gsl_function F

        F.function = &integrand          # works 
        # F.function = &self._integrand  # doesn't work

        cdef double params[1]
        params[0] = alpha
        F.params = &params

        cdef double epsabs = 0.
        cdef double epsrel = 1e-7
        gsl_integration_qags(&F, a, b, epsabs, epsrel, 1000, W, &result, &error)
        gsl_integration_workspace_free(W)

        return result


    cdef double _integrand(self, double x, void * params):
        """integrand implemented inside class """

        cdef double alpha = (<double_ptr> params)[0]
        cdef double f = log(alpha*x) / sqrt(x)
        return f

上面的代码在使用该类之外的 F.function = &integrand函数时可以编译并正确运行（ F.function = &integrand ）。 但是，将这一行更改为下面注释掉的那一行（ F.function = &self._integrand ），以代替使用类内部的 F.function = &self._integrand函数，会导致以下编译错误：

cython_class_gsl.pyx:31:21: Cannot assign type 'double (*)(CalcSomething, double, void *)' to 'double (*)(double, void *)'

这是有道理的，因为我在cGslInteg.pxd对gsl_function的cGslInteg.pxd是：

cdef extern from "gsl/gsl_math.h":

    # Definition of an arbitrary function with parameters
    ctypedef struct gsl_function:
        double (* function) (double x, void * params)
        void * params

我的问题是：我可以重新声明gsl_function以便它期望使用double (*)(PythonObject, double, void *)类型的东西，还是可以包装self._integrand使其看起来像double (*)( double, void *) ？

编辑：一些额外的说明，以使其更接近于现实生活中的问题/问题：

1. self._integrand任何包装都必须在CalcSomething类中定义。
2. 积分参数alpha不能是类变量（即必须在params参数中传递给被积分数）

Answer 1

这就是params目的。 你会做这样的事情（大大削减了例子...）

from libc.math cimport log,sqrt

cdef class CalcSomething:   
    cdef double integrand(self, double x, double alpha):
        return log(alpha*x)/sqrt(x)

cdef double wrapped_integrand_func(double x, void* params):
    cdef object params_as_object = <object>params
    cdef CalcSomething instance = params_as_object[0] # we need to know the type to use cdef functions
    alpha = params_as_object[1]
    return instance.integrand(x,alpha)

def test(alpha):
    cdef object o = (CalcSomething(),alpha) # store Calc something and alpha as a tuple
    cdef void* o_ptr = <void*>o # be careful with reference counts here - o_ptr doesn't keep o alive!
    print(wrapped_integrand_func(4.3,o_ptr))

这显然不是包装绑定方法的通用解决方案，但是在这种情况下，这正是gsl允许您传递void* 。

一个警告是，您必须确保o保持生存状态， o_ptr您想使用o_ptr 。

更新 （以匹配稍作修改的问题）：

积分参数alpha不能是类变量（即必须在params参数中传递给被积分数）

这很容易做到。 在我的原始代码中，我使用了一个类变量，但是现在我将它们分别作为一个元组传递给了它们。