使用 CMake ExternalProject 将预编译库集成到 C++ 代码库中

Question

我想将CasADi作为ExternalProject集成到基于CMake的 C++ 代码库中。 为此，我想使用预编译库，因为不推荐从源代码构建。 到目前为止，我只写了以下内容：

ExternalProject_Add(
  casadi-3.5.5
  URL https://github.com/casadi/casadi/releases/download/3.5.5/casadi-linux-py39-v3.5.5-64bit.tar.gz
  CONFIGURE_COMMAND ""
  BUILD_COMMAND ""
  INSTALL_COMMAND ""
  PREFIX ${CMAKE_BINARY_DIR}/external/casadi)

我注意到所有二进制文件都已正确下载到指定文件夹中。 但是，我不知道如何将我的目标链接到CasADi ，也不知道如何找到 package。

Answer 1

ExternalProject_Add 有一个自然的问题：

ExternalProject_Add 仅在构建时执行命令。

因此，下载不会发生在项目的配置阶段，这使得使用find_package变得困难，因为在第一次配置运行期间找不到文件。

以这个 CMakeLists.txt 为例：

cmake_minimum_required(VERSION 3.21)
project(untitled)

set(CMAKE_CXX_STANDARD 17)

add_executable(untitled main.cpp)

include(ExternalProject)
ExternalProject_Add(
        casadi-3.5.5
        URL https://github.com/casadi/casadi/releases/download/3.5.5/casadi-linux-py39-v3.5.5-64bit.tar.gz
        CONFIGURE_COMMAND ""
        BUILD_COMMAND ""
        INSTALL_COMMAND ""
        PREFIX ${CMAKE_BINARY_DIR}/external/casadi)

find_package(casadi HINTS ${CMAKE_BINARY_DIR}/external/casadi/src/casadi-3.5.5/casadi)

target_link_libraries(untitled casadi)

要使用它，您必须执行以下操作：

1. 配置您的项目

mkdir build
cd build
cmake ..

2. 构建（下载）casadi-3.5.5

cmake --build . --target casadi-3.5.5

3. 重新配置你的项目，因为现在find_package会找到需要的文件

cmake ..

4. 建立你的目标

cmake --build .

---

如果你想要一步构建，有办法解决这个问题

• 使用FetchContent
• 使用所有ExternalProject_Add命令在子文件夹中创建子 cmake 项目，并通过execute_process调用在您自己的 CMakeLists.txt 中手动执行适当的构建（下载）步骤： https://stackoverflow.com/a/37554269/8088550

---

下面是第二个选项的示例，它可能更好，因为 FetchContent 不具备 ExternalProject 的全部功能。

• main.cpp

#include <casadi/casadi.hpp>

int main()
{
    casadi_printf("This works!");
    return 0;
}

• CMakeLists.txt

cmake_minimum_required(VERSION 3.20)
project(untitled)

set(CMAKE_CXX_STANDARD 17)

# some default target
add_executable(untitled main.cpp)

# Configure and build external project
file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/external)
execute_process(
        COMMAND ${CMAKE_COMMAND} ${CMAKE_SOURCE_DIR}/external
        WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/external
)
execute_process(
        COMMAND ${CMAKE_COMMAND} --build ${CMAKE_BINARY_DIR}/external
)

# find and link externals
find_package(casadi REQUIRED HINTS ${CMAKE_BINARY_DIR}/external/external/casadi/src/casadi-3.5.5/casadi)
target_link_libraries(untitled casadi)

• external/CMakeLists.txt

cmake_minimum_required(VERSION 3.20)
project(external)

include(ExternalProject)
ExternalProject_Add(
        casadi-3.5.5
        URL https://github.com/casadi/casadi/releases/download/3.5.5/casadi-linux-py39-v3.5.5-64bit.tar.gz
        CONFIGURE_COMMAND ""
        BUILD_COMMAND ""
        INSTALL_COMMAND ""
        PREFIX ${CMAKE_BINARY_DIR}/external/casadi)

重点是在external/CMakeLists.txt下有另一个 cmake 项目，它通过来自主 cmake 项目的execute_process调用进行配置和构建。 请注意，您现在可以在配置阶段拥有find_package(casadi REQUIRED...) ，因为下载将在之前进行。