When I call a macro function twice (inside a section) I get this compile error:
Error: label "CheckForRMSCustomisationLoop:" already declared in section
I understand its because I am defining a label(jump) twice, is that correct?
How can I avoid this problem?
Do I HAVE to convert the macro to a function or is there an easier way? Because converting to a function means I cant pass parameters I have to use the stack.
Outfile "RequireAdmin.exe"
RequestExecutionLevel admin ;Require admin rights on NT6+ (When UAC is turned on)
!include LogicLib.nsh
!macro Test param1 param2
TestLabel1:
DetailPrint "TestLabel1"
TestLabel2:
DetailPrint "TestLabel2"
!macroend
Section
!insertmacro Test 1 2
!insertmacro Test 3 4
IfErrors 0 +2
MessageBox MB_ICONEXCLAMATION|MB_OK "Unable to write to the registry" IDOK +1
SectionEnd
Function TestFunct # I MISS MY PARAMS :(
Pop $R9 # represents param2: but actually having param2 is SO MUCH more descriptive
Pop $R8
TestLabel1:
DetailPrint "TestLabel1"
TestLabel2:
DetailPrint "TestLabel2"
FunctionEnd
/* Usage
Push 1
Push 2
Call TestFunct
Push 3
Push 4
Call TestFunct
*/
You're right, you're defining labels TestLabel1
and TestLabel2
twice.
You could make your label names unique using this method:
!macro Test param1 param2
!define ID ${__LINE__}
TestLabel1_${ID}:
DetailPrint "TestLabel1"
TestLabel2_${ID}:
DetailPrint "TestLabel2"
!macroend
More information here:
It appears this is a solution and its pretty elegant too:
!macro Test param1 param2 uid
TestLabel1_${uid}:
DetailPrint "TestLabel1"
TestLabel2_${uid}:
DetailPrint "TestLabel2"
!macroend
# Usage:
Section
!insertmacro Test 1 2 ${__LINE__}
!insertmacro Test 3 4 ${__LINE__}
SectionEnd
!macro test p1
!define test_ "test${__LINE__}"
IntCmp ${p1} 3 ${test_}double 0
DetailPrint ${p1}
Goto ${test_}end
${test_}double:
IntOp $0 ${p1} * 2
DetailPrint $0
${test_}end:
!undef test_
!macroend
; If the macro is very large and you call it multiple times it might be better to use a function or a macro/function hybrid:
!include util.nsh
!macro testmacroasfunction
Pop $0
IntCmp $0 3 double 0
DetailPrint $0
Goto end
double:
IntOp $0 $0 * 2
DetailPrint $0
end:
!macroend
!macro test2 p1
Push ${p1}
${CallArtificialFunction} testmacroasfunction
!macroend
section
!insertmacro test 2
!insertmacro test 3
!insertmacro test 4
!insertmacro test2 2
!insertmacro test2 3
!insertmacro test2 4
sectionend
The technical post webpages of this site follow the CC BY-SA 4.0 protocol. If you need to reprint, please indicate the site URL or the original address.Any question please contact:yoyou2525@163.com.