Unity3d中的輪廓着色器

Question

我正在嘗試將我從網上獲得的這個着色器配置為具有白色輪廓而不是黑色輪廓。 但“_OutlineColor（“輪廓顏色”，顏色）=（1,1,1,1）”不起作用。 我是統一的新手以及事情如何運作，所以我希望你能幫助我。 這是完整的着色器：

Shader "Outlined/Diffuse" {
    Properties {
        _Color ("Main Color", Color) = (0,0,0,0)
        _OutlineColor ("Outline Color", Color) = (1,1,1,1)
        _Outline ("Outline width", Range (.002, 0.03)) = 5
        _MainTex ("Base (RGB)", 2D) = "white" { }
    }

CGINCLUDE
#include "UnityCG.cginc"

struct appdata {
    float4 vertex : POSITION;
    float3 normal : NORMAL;
};

struct v2f {
    float4 pos : POSITION;
    float4 color : COLOR;
};

uniform float _Outline;
uniform float4 _OutlineColor;

v2f vert(appdata v) {
    // just make a copy of incoming vertex data but scaled according to normal direction
    v2f o;
    o.pos = mul(UNITY_MATRIX_MVP, v.vertex);

    float3 norm   = mul ((float3x3)UNITY_MATRIX_IT_MV, v.normal);
    float2 offset = TransformViewToProjection(norm.xy);

    o.pos.xy += offset * o.pos.z * _Outline;
    o.color = _OutlineColor;
    return o;
}
ENDCG

    SubShader {
        //Tags {"Queue" = "Geometry+100" }
CGPROGRAM
#pragma surface surf Lambert

sampler2D _MainTex;
fixed4 _Color;

struct Input {
    float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
    fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
    o.Albedo = c.rgb;
    o.Alpha = c.a;
}
ENDCG

        // note that a vertex shader is specified here but its using the one above
        Pass {
            Name "OUTLINE"
            Tags { "LightMode" = "Always" }
            Cull Front
            ZWrite On
            ColorMask RGB
            Blend SrcAlpha OneMinusSrcAlpha
            //Offset 50,50

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            half4 frag(v2f i) :COLOR { return i.color; }
            ENDCG
        }
    }

    SubShader {
CGPROGRAM
#pragma surface surf Lambert

sampler2D _MainTex;
fixed4 _Color;

struct Input {
    float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
    fixed4 c = tex2D(_MainTex, IN.uv_MainTex) * _Color;
    o.Albedo = c.rgb;
    o.Alpha = c.a;
}
ENDCG

        Pass {
            Name "OUTLINE"
            Tags { "LightMode" = "Always" }
            Cull Front
            ZWrite On
            ColorMask RGB
            Blend SrcAlpha OneMinusSrcAlpha

            CGPROGRAM
            #pragma vertex vert
            #pragma exclude_renderers gles xbox360 ps3
            ENDCG
            SetTexture [_MainTex] { combine primary }
        }
    }

    Fallback "Diffuse"
}

Answer 1

您分配給“_OutlineColor”的“(1,1,1,1)”描述了一個默認值。 當您創建使用該着色器的新材質（此處為“輪廓/漫反射”）時，會考慮該值。 只需創建新材質並將您的着色器分配給它。 您會注意到這次的輪廓顏色將是白色。 您也可以簡單地在編輯器中選擇您的材料並通過檢查器窗口更改輪廓顏色。

至於您的問題 - 可能您已經創建了一種與您描述的着色器相結合的新材料，在您將着色器的主體從黑色 (0,0,0,1) 更改為白色 (1,1,1,1 ) 顏色（我認識着色器的主體，所以我假設為黑色）。 這意味着默認的黑色已經分配給材料。 如果你想改變顏色，就像我上面寫的，通過編輯檢查員在材料上做。