A real braintease right here.
I want to mark the transitions between de X1's. So the transition from A -> B, B-> A and B-> C, C-> B.
This is to reduce my dataset to only those records that have a transition.
The end goal is to calculate the days between the date when the last time X1 A occured and the first time that X1 B had occured.
For example:
ID1 -> Transition A to B, Dates 2018-01-20 and 2018-02-01. Then the answer has to be x number of days between.
OR
Example 2: ID1 -> Transition A to B, Dates 2018-02-16 and 2018-03-01. Then the answer has to be x number of days between.
ID X1 Date
1 A 2018-01-01
1 A 2018-01-20
1 B 2018-02-01
1 A 2018-02-15
1 A 2018-02-16
1 B 2018-03-01
2 B 2018-01-01
2 C 2018-03-05
2 C 2018-03-06
2 C 2018-03-08
2 B 2018-03-20
I already have this loop but this loop takes way too long (0,3 second per record):
DECLARE @Loop INT
DECLARE @MAXROWS INT
SET @Loop = 1
SET @MAXROWS = (SELECT COUNT (*) FROM Y_Table)
WHILE (@Loop <= @MAXROWS)
BEGIN
UPDATE Y_Table
SET Y_Table.Test_MIN = (CASE WHEN
(SELECT Y_Table.ID FROM Y_Table WHERE LIFE_CYCLE = @Loop) =
(SELECT Y_Table.ID FROM Y_Table WHERE LIFE_CYCLE = @Loop + 1) AND
(SELECT Y_Table.Date FROM Y_Table WHERE LIFE_CYCLE = @Loop) <
(SELECT Y_Table.Date FROM Y_Table WHERE LIFE_CYCLE = @Loop + 1) AND
(SELECT Y_Table.X1 FROM Y_Table WHERE LIFE_CYCLE = @Loop) <>
(SELECT Y_Table.X1 FROM Y_Table WHERE LIFE_CYCLE = @Loop + 1)
THEN '1' ELSE '0' END)
FROM Y_Table
WHERE
LIFE_CYCLE = @Loop
UPDATE Y_Table
SET Y_Table.Test_MAX = (CASE WHEN
(SELECT Y_Table.ID FROM Y_Table WHERE LIFE_CYCLE = @Loop) =
(SELECT Y_Table.ID FROM Y_Table WHERE LIFE_CYCLE = @Loop + 1) AND
(SELECT Y_Table.Date FROM Y_Table WHERE LIFE_CYCLE = @Loop) <
(SELECT Y_Table.Date FROM Y_Table WHERE LIFE_CYCLE = @Loop + 1) AND
(SELECT Y_Table.X1 FROM Y_Table WHERE LIFE_CYCLE = @Loop) <>
(SELECT Y_Table.X1 FROM Y_Table WHERE LIFE_CYCLE = @Loop + 1)
THEN '1' ELSE '0' END)
FROM Y_Table
WHERE
LIFE_CYCLE = @Loop + 1
PRINT @Loop
SET @Loop = @Loop + 1
END
How to solve this?
Something like this
DECLARE @data table (ID int, X1 char(1), myDate date)
INSERT @data VALUES (1, 'A', '2018-01-01'),
(1, 'A', '2018-01-20'),
(1, 'B', '2018-02-01'),
(1, 'A', '2018-02-15'),
(1, 'A', '2018-02-16'),
(1, 'B', '2018-03-01'),
(2, 'B', '2018-01-01'),
(2, 'C', '2018-03-05'),
(2, 'C', '2018-03-06'),
(2, 'C', '2018-03-08'),
(2, 'B', '2018-03-20');
WITH GetNextRows AS (
SELECT
*,
NextX1 = LEAD (X1) OVER (PARTITION BY ID ORDER BY myDate),
NextDate = LEAD (myDate) OVER (PARTITION BY ID ORDER BY myDate)
FROM
@data
)
SELECT
*,
Transation = CONCAT(X1, ' -> ', NextX1),
DaysGap = DATEDIFF(DAY, myDate, NextDate)
FROM
GetNextRows
WHERE
NextX1 <> X1;
ID X1 myDate NextX1 NextDate Transation DaysGap
1 A 2018-01-20 B 2018-02-01 A -> B 12
1 B 2018-02-01 A 2018-02-15 B -> A 14
1 A 2018-02-16 B 2018-03-01 A -> B 13
2 B 2018-01-01 C 2018-03-05 B -> C 63
2 C 2018-03-08 B 2018-03-20 C -> B 12
You can use LAG
to get the previous X1
and Date
values. If the current X1
value is different from the previous, then you have a transition and can calculated the diff in days.
DECLARE @DataSource TABLE
(
[ID] SMALLINT
,[X1] CHAR(1)
,[Date] DATE
);
INSERT INTO @DataSource ([ID], [X1], [Date])
VALUES ('1', 'A', '2018-01-01')
,('1', 'A', '2018-01-20')
,('1', 'B', '2018-02-01')
,('1', 'A', '2018-02-15')
,('1', 'A', '2018-02-16')
,('1', 'B', '2018-03-01')
,('2', 'B', '2018-01-01')
,('2', 'C', '2018-03-05')
,('2', 'C', '2018-03-06')
,('2', 'C', '2018-03-08')
,('2', 'B', '2018-03-20');
SELECT *
,IIF
(
[X1] <> LAG([X1], 1, NULL) OVER(PARTITION BY [ID] ORDER BY [Date] ASC)
,DATEDIFF(DAY, LAG([Date], 1, NULL) OVER(PARTITION BY [ID] ORDER BY [Date] ASC), [Date])
,NULL
) AS [TransitionInDays]
FROM @DataSource;
Note, you need SQL Server 2012+ to use LAG
. Let me know if this is not the case.
The technical post webpages of this site follow the CC BY-SA 4.0 protocol. If you need to reprint, please indicate the site URL or the original address.Any question please contact:yoyou2525@163.com.