Byte collection to string on clojure

Question

The following code

(defn caesar-block-cypher
  "Computes the caesar block cypher for the given text with the k key. Returns an array of bytes"
  [k text]
  (let [byte-string (.getBytes text)]
    (loop [return-byte-array [] byte-string byte-string]
      (if (= '() byte-string)
        return-byte-array
        (recur
          (conj return-byte-array (byte (+ k (first byte-string))))
          (rest byte-string))))))

Returns an array of bytes after processing the caesar cipher with key k at text. I want to convert back the byte array to a string or perform the cipher over the string directly, but (new String return-byte-array) doesn't work. Any suggestions?

---

EDIT: Thanks for the responses. I recodified this on a more functional style (that actually works):

(defn caesar-block-cypher
  "Computes the caesar block cypher for the given text with the k key."
  [k text & more]
    (let [byte-string (.getBytes (apply str text (map str more)))]
      (apply str (map #(char (mod (+ (int %) k) 0x100)) byte-string))))

Answer 1

(let [byte-array (caesar-block-cypher 1 "Hello, world!")]
    (apply str (map char byte-array)))

Answer 2

Use java's String constructor to create string quickly like this,

(let [b (caesar-block-cypher 1 "Hello World")]
  (String. b))

Answer 3

AFAIK ceaser chipher just shifts chars why are you dealing with bytes,

(let [s "Attack"
      k 1
      encoded (map #(char (+ (int %) k)) s)
      decoded (map #(char (- (int %) k)) encoded)]
  (apply str decoded))

Answer 4

You can use slurp , it also works for byte arrays:

From https://clojuredocs.org/clojure.core/slurp#example-588dd268e4b01f4add58fe33

;; you can read bytes also

(def arr-bytes (into-array Byte/TYPE (range 128)))
(slurp arr-bytes)